svg-path:
wsp* subpath* wsp*

subpath:
moveto subpath-elements?

subpath-elements:
subpath-element (wsp* subpath-element)*

subpath-element:
closepath
| lineto
| horizontal-lineto
| vertical-lineto
| curveto
| smooth-curveto
| quadratic-bezier-curveto
| smooth-quadratic-bezier-curveto
| elliptical-arc

moveto:
( "M" | "m" ) wsp* moveto-argument-sequence

moveto-argument-sequence:
coordinate-pair (comma-wsp? coordinate-pair)*

closepath:
("Z" | "z")

lineto:
( "L" | "l" ) wsp* lineto-argument-sequence

lineto-argument-sequence:
coordinate-pair (comma-wsp? coordinate-pair)*

horizontal-lineto:
( "H" | "h" ) wsp* horizontal-lineto-argument-sequence

horizontal-lineto-argument-sequence:
| coordinate (comma-wsp? coordinate)*

vertical-lineto:
( "V" | "v" ) wsp* vertical-lineto-argument-sequence

vertical-lineto-argument-sequence:
coordinate (comma-wsp? coordinate)*

curveto:
( "C" | "c" ) wsp* curveto-argument-sequence

curveto-argument-sequence:
curveto-argument (comma-wsp? curveto-argument)*

curveto-argument:
coordinate-pair comma-wsp? coordinate-pair comma-wsp? coordinate-pair

smooth-curveto:
( "S" | "s" ) wsp* smooth-curveto-argument-sequence

smooth-curveto-argument-sequence:
smooth-curveto-argument (comma-wsp? smooth-curveto-argument)*

smooth-curveto-argument:
coordinate-pair comma-wsp? coordinate-pair

quadratic-bezier-curveto:
( "Q" | "q" ) wsp* quadratic-bezier-curveto-argument-sequence

quadratic-bezier-curveto-argument-sequence:
quadratic-bezier-curveto-argument (comma-wsp? 
quadratic-bezier-curveto-argument)*

quadratic-bezier-curveto-argument:
coordinate-pair comma-wsp? coordinate-pair

smooth-quadratic-bezier-curveto:
( "T" | "t" ) wsp* smooth-quadratic-bezier-curveto-argument-sequence

smooth-quadratic-bezier-curveto-argument-sequence:
coordinate-pair (comma-wsp? coordinate-pair)*

elliptical-arc:
( "A" | "a" ) wsp* elliptical-arc-argument-sequence

elliptical-arc-argument-sequence:
elliptical-arc-argument (comma-wsp? elliptical-arc-argument)*

elliptical-arc-argument:
nonnegative-number comma-wsp? nonnegative-number comma-wsp? 
number comma-wsp? flag comma-wsp? flag comma-wsp? coordinate-pair

coordinate-pair:
coordinate comma-wsp? coordinate

coordinate:
number

nonnegative-number:
integer-constant
| floating-point-constant

number:
sign? integer-constant
| sign? floating-point-constant

flag:
"0" | "1"

comma-wsp:
(wsp+ comma? wsp*) | (comma wsp*)

comma:
","

integer-constant:
digit+

floating-point-constant:
fractional-constant exponent?
| digit+ exponent

fractional-constant:
digit* "." digit+
| digit+ "."

exponent:
( "e" | "E" ) sign? digit+

sign:
"+" | "-"

digit:
"0" | "1" | "2" | "3" | "4" | "5" | "6" | "7" | "8" | "9"

wsp:
(#x20 | #x9 | #xD | #xA)