head	1.2;
access;
symbols;
locks
	connolly:1.2; strict;
comment	@# @;


1.2
date	2000.04.09.07.29.30;	author connolly;	state Exp;
branches;
next	1.1;

1.1
date	2000.04.09.06.41.54;	author connolly;	state Exp;
branches;
next	;


desc
@@


1.2
log
@*** empty log message ***
@
text
@svg-path:
wsp* subpath* wsp*

subpath:
moveto subpath-elements?

subpath-elements:
subpath-element (wsp* subpath-element)*

subpath-element:
closepath
| lineto
| horizontal-lineto
| vertical-lineto
| curveto
| smooth-curveto
| quadratic-bezier-curveto
| smooth-quadratic-bezier-curveto
| elliptical-arc

moveto:
( "M" | "m" ) wsp* moveto-argument-sequence

moveto-argument-sequence:
coordinate-pair (comma-wsp? coordinate-pair)*

closepath:
("Z" | "z")

lineto:
( "L" | "l" ) wsp* lineto-argument-sequence

lineto-argument-sequence:
coordinate-pair (comma-wsp? coordinate-pair)*

horizontal-lineto:
( "H" | "h" ) wsp* horizontal-lineto-argument-sequence

horizontal-lineto-argument-sequence:
| coordinate (comma-wsp? coordinate)*

vertical-lineto:
( "V" | "v" ) wsp* vertical-lineto-argument-sequence

vertical-lineto-argument-sequence:
coordinate (comma-wsp? coordinate)*

curveto:
( "C" | "c" ) wsp* curveto-argument-sequence

curveto-argument-sequence:
curveto-argument (comma-wsp? curveto-argument)*

curveto-argument:
coordinate-pair comma-wsp? coordinate-pair comma-wsp? coordinate-pair

smooth-curveto:
( "S" | "s" ) wsp* smooth-curveto-argument-sequence

smooth-curveto-argument-sequence:
smooth-curveto-argument (comma-wsp? smooth-curveto-argument)*

smooth-curveto-argument:
coordinate-pair comma-wsp? coordinate-pair

quadratic-bezier-curveto:
( "Q" | "q" ) wsp* quadratic-bezier-curveto-argument-sequence

quadratic-bezier-curveto-argument-sequence:
quadratic-bezier-curveto-argument (comma-wsp? 
quadratic-bezier-curveto-argument)*

quadratic-bezier-curveto-argument:
coordinate-pair comma-wsp? coordinate-pair

smooth-quadratic-bezier-curveto:
( "T" | "t" ) wsp* smooth-quadratic-bezier-curveto-argument-sequence

smooth-quadratic-bezier-curveto-argument-sequence:
coordinate-pair (comma-wsp? coordinate-pair)*

elliptical-arc:
( "A" | "a" ) wsp* elliptical-arc-argument-sequence

elliptical-arc-argument-sequence:
elliptical-arc-argument (comma-wsp? elliptical-arc-argument)*

elliptical-arc-argument:
nonnegative-number comma-wsp? nonnegative-number comma-wsp? 
number comma-wsp? flag comma-wsp? flag comma-wsp? coordinate-pair

coordinate-pair:
coordinate comma-wsp? coordinate

coordinate:
number

nonnegative-number:
integer-constant
| floating-point-constant

number:
sign? integer-constant
| sign? floating-point-constant

flag:
"0" | "1"

comma-wsp:
(wsp+ comma? wsp*) | (comma wsp*)

comma:
","

integer-constant:
digit+

floating-point-constant:
fractional-constant exponent?
| digit+ exponent

fractional-constant:
digit* "." digit+
| digit+ "."

exponent:
( "e" | "E" ) sign? digit+

sign:
"+" | "-"

digit:
"0" | "1" | "2" | "3" | "4" | "5" | "6" | "7" | "8" | "9"

wsp:
(#x20 | #x9 | #xD | #xA)

@


1.1
log
@Initial revision
@
text
@d2 1
a2 5
wsp* subpaths? wsp*

subpaths:
subpath
| subpath subpaths
d8 1
a8 2
subpath-element
| subpath-element wsp* subpath-elements
d25 1
a25 2
coordinate-pair
| coordinate-pair comma-wsp? lineto-argument-sequence
d34 1
a34 2
coordinate-pair
| coordinate-pair comma-wsp? lineto-argument-sequence
d40 1
a40 2
coordinate
| coordinate comma-wsp? horizontal-lineto-argument-sequence
d46 1
a46 2
coordinate
| coordinate comma-wsp? vertical-lineto-argument-sequence
d52 1
a52 2
curveto-argument
| curveto-argument comma-wsp? curveto-argument-sequence
d61 1
a61 2
smooth-curveto-argument
| smooth-curveto-argument comma-wsp? smooth-curveto-argument-sequence
d70 2
a71 3
quadratic-bezier-curveto-argument
| quadratic-bezier-curveto-argument comma-wsp? 
quadratic-bezier-curveto-argument-sequence
d80 1
a80 2
coordinate-pair
| coordinate-pair comma-wsp? smooth-quadratic-bezier-curveto-argument-sequence
d86 1
a86 2
elliptical-arc-argument
| elliptical-arc-argument comma-wsp? elliptical-arc-argument-sequence
d116 1
a116 1
digit-sequence
d120 1
a120 1
| digit-sequence exponent
d123 2
a124 2
digit-sequence? "." digit-sequence
| digit-sequence "."
d127 1
a127 1
( "e" | "E" ) sign? digit-sequence
a130 4

digit-sequence:
digit
| digit digit-sequence
@