Menüs

menubutton widgetpath -text Name -menu menupath

menu widgetpath

widgetpath add Command

• command
  Wie Button-Widgets, stellen sie einen String oder eine Bitmap dar und evaluieren ein Tcl-Skript, wenn sie mit der ersten Maustaste angeklickt werden.
• checkbutton
  Funktionalitäten genauso wie Ihre Namensvettern unter den Button-Widgets. Ein rechteckiger Selektor zeigt wie bei den Checkbutton-Widgets den Zustand des Eintrags an.
• radiobutton
  Dieser Eintrag in einem Menu-Widget verhält sich genauso wie ein Radiobutton. Außerdem zeigen sie auch den gleichen rautenförmigen Selektor wie die Radiobuttons an.
• cascade
  Ähnlich einem Menubutton-Widget. Sobald sich der Mauszeiger über einem Eintrag dieser Art befindet, wird ein Untermenü geöffnet. Der Benutzer kann die Maus dann in dieses Untermenü bewegen und dort Einträge wie gewohnt auswählen. Ist ein Menüpunkt aktiviert worden, werden sowohl das Untermenü als auch alle ihm übergeordneten Menüs geschlossen. Um ein Untermenü zu erstellen, muß es lediglich als Widget erzeugt und über die Ressource -menu eines Eintrags vom Typ cascade mit einem übergeordneten Menu-Widget verbunden werden. Ein Untermenü selbst kann weitere Untermenüs enthalten. Der Verschachtelungstiefe sind durch Tk keine Grenzen gesetzt.
• separator
  Dient zur Auflockerung von Menüs, wobei ein horizontaler Strich an der Stelle von Einträgen dieser Art erscheint. Diese Einträge reagieren nicht auf die Maus.

Benutzer können auch ohne Hilfe der Maus Menüpunkte öffnen und einen gewünschten Eintrag auswählen. Diese Technik wird in Tk Keyboard-Traversal   genannt. Dazu wird in einem Menüpunkt ein Zeichen mit der Ressource -underline festgelegt. Drückt der Benutzer dieses Zeichen zusammen mit der Alt-Taste, so wird das darunterliegende Untermenü geöffnet bzw. der dazu passende Menüeintrag aktiviert. Mit den Pfeiltasten kann auf einen beliebigen Eintrag verzweigt, und mit der Return-Taste der ausgewählte Eintrag aktiviert werden. Eine andere Möglichkeit bietet die Funktionstaste F10, mit deren Hilfe direkt der am weitesten links stehende Menüeintrag in der Menüleiste aktiviert wird.

Eine weitere Vereinfachung der Arbeit mit Menüs bringen dem Benutzer sogenannte Tastenkürzel  . Das sind spezielle Tastenkombinationen über die direkt ein Menüpunkt aktiviert werden kann, ohne daß das Menü in dem sich der Eintrag befindet geöffnet werden muß. Zu diesem Zweck besitzen Menu-Widgets die Ressource -accelerator, mit der die Tastenkombination, die die entsprechende Aktion auslösen soll, rechts vom Eintrag angezeigt wird (siehe Abbildung Eintrag Kopieren Ctrl-c). Das Setzen der Ressource -accelerator allein reicht nicht aus, um die gewünschte Funktionalität an das Tastenkürzel zu binden. Es muß mit dem bind-Befehl eine entsprechende Verknüpfung zwischen der Tastenkombination und der Funktion erzeugt werden.

Das folgende Beispiel soll diese Regeln verdeutlichen.

 
Figure: Menu-Widget

   #!/usr/bin/wish -f
   #-----------------------------------------------------------------#
   #
   # Programmname : menu.tk
   # TK-Version 4.0 TCL-Version 7.4
   # Erstellungsatum: Sat May 4 14:21:11 GMT 1996
   #
   #-----------------------------------------------------------------#

   frame .menu -relief raised -borderwidth 1
   label .label -text "Menüdemo"

   # Pulldown-Menü 'Datei'
   menubutton .menu.datei -text "Datei" -menu .menu.datei.m -underline 0
   menu .menu.datei.m
   .menu.datei.m add command -label "Öffnen" -underline 0   \
         -command "puts Öffnen" 
   .menu.datei.m add command -label "Speichen" -underline 0 \
         -command "puts Speichern" 
   .menu.datei.m add separator
   .menu.datei.m add command -label "Ende" -command exit -underline 0

   # Pulldown-Menü 'Bearbeiten'
   menubutton .menu.bearbeiten -text "Bearbeiten" -underline 0 \
         -menu .menu.bearbeiten.m 
   menu .menu.bearbeiten.m
   .menu.bearbeiten.m add command -label "Einfügen" -underline 0 \ 
         -command "puts Einfügen" -accelerator Ctrl+v
   .menu.bearbeiten.m add command -label "Kopieren" -underline 0 \ 
         -command "puts Kopieren" -accelerator Ctrl+c
   .menu.bearbeiten.m add separator 
   .menu.bearbeiten.m add cascade -label "Optionen" -underline 0 \
         -menu .menu.bearbeiten.m.opt 
   .menu.bearbeiten.m add cascade -label "Untermenü" -underline 0 \
         -menu .menu.bearbeiten.m.sub 

   # Untermenü mit Optionen
   menu .menu.bearbeiten.m.opt
   .menu.bearbeiten.m.opt add check -label "Kontrollkästchen 1" -underline 0
   .menu.bearbeiten.m.opt add check -label "Kontrollkästchen 2" -underline 1
   .menu.bearbeiten.m.opt add separator
   .menu.bearbeiten.m.opt add radio -label "Option 1" -underline 7
   .menu.bearbeiten.m.opt add radio -label "Option 2" -underline 7

   # normales Untermenü zum Spezial-Menü
   menu .menu.bearbeiten.m.sub
   .menu.bearbeiten.m.sub add command -label "Untermenüeintrag 1" -underline 17
   .menu.bearbeiten.m.sub add command -label "Untermenüeintrag 2" -underline 17
   .menu.bearbeiten.m.sub add command -label "Untermenüeintrag 3" -underline 17

   # Pulldown-Menü 'Hilfe'
   menubutton .menu.hilfe -text "Hilfe" -menu .menu.hilfe.m -underline 0
   menu .menu.hilfe.m
   .menu.hilfe.m add command -label "Über" -underline 0 \
      -command {puts "Testprogramm: Arbeiten mit Menüs unter TK"}

   bind . <Control-Key-c> {
        puts "Kopieren"
   }

   bind . <Control-Key-v> {
        puts "Einfügen"
   }

   # menü anzeigen
   pack .menu -side top -fill x
   pack .label -padx 100 -pady 40
   pack .menu.datei .menu.bearbeiten -side left
   pack .menu.hilfe -side right